10 REM **** FAKTURERING ****
20 DIM A(35,6),A$(35),B(3),T$(6,2),T(3)
30 GOTO 4190
40 :
60 F$="FAKTUUR KOP ":GOSUB 390
70 PRINT:PRINT"INLEZEN KOP-FAKTUUR ":GOSUB 300                
80 IF S=2 THEN 4020
90 OPEN "I",1,"KOPFAKT"
100 INPUT #1,N1$,N2$,N3$ 
101 INPUT #1,N4$,N5$ 
102 INPUT #1,N6$,N7$
103 INPUT #1,N8$
110 CLOSE
120 :
125 RETURN
140 B1=0 :REM INGEVOERDE PRIJXEN ZIJN EXCL BTW.
150      :REM INGEVORDE PRIJZEN ZIJN INCL BTW
160 Y4=0 :K=0:G=1
170 P1=2 :REM AANTAL KOPIE-FACTUREN
175 GOSUB 8000
180 REM B(1) BTW NUL TARIEF   
190 REM B(2) BTW TARIEF LAAG
200 REM B(3) BTW TARIEF HOOG
210 T$(1,1)= "KLANTNAAM................."
220 T$(2,1)= "T.A.V....................."
230 T$(3,1)= "ADRES + HUISNR............"
240 T$(4,1)= "POSTCODE + WOONPL........."
250 T$(5,1)= "LAND......................"
260 T$(6,1)= "ORDERNR KLANT............."
270 LF$=CHR$(138):FF$=CHR$(12) :REM LINEFEED/FORMFEED
280 RETURN
290 :
300 REM ** JA/NEE **
310 PRINT B$+ " <JA/NEE> ";
320 INPUT L$ :L$ =LEFT$(L$,1) :S=0
330 IF L$="J" THEN S=1
340 IF L$="N" THEN S=2
350 IF S=0 THEN 310
360 RETURN
370 :
380 REM *** KOP ***
390 PRINT CHR$(27)"E"
400 PRINT"*** FAKTURERING ***"
410 PRINT F$;TAB(30)"FAKTUURDATUM :";D$
420 PRINT
430 IF S1=0 THEN 480
440 PRINT"KLANTNR : ";K;TAB(30)"KLANT  :";T$(1,2)
450 PRINT"AANTAL FAKTUURREGELS :"; N
455 PRINT"========================================================================"
460 PRINT"RGL ART-NR OMSCHRIJVING          PRIJS       AANTAL ";
470 PRINT"   BEDRAG     BTW"
480 RETURN
490 :
500 REM ** DATUM **
510 F$= "-DATUM-":S1=0
520 GOSUB 390
530 PRINT"WAT IS DE FAKTURERINGS-DATUM <DD,MM,JJ> ";
540 INPUT Y1,Y2,Y3
550 IF Y1=0 AND Y3=0 THEN 630
560 IF Y1<0 OR Y1 >31 THEN 520
570 IF Y2 <0 OR Y2 >12 THEN 520
580 IF Y3 <83 OR Y3>100 THEN 520
590 H$=STR$(Y1):D$=RIGHT$(H$,LEN(H$)-1)+" "
600 H$=LEFT$("JANFEBMRTAPRMEIJUNJULAUGSEPOKTNOVDEC",Y2*3)
610 D$=D$+RIGHT$(H$,3):D$=D$+STR$(Y3+1900)
620 Y4=Y3*10000+Y2*100+Y1 :REM GENORM DATUM
630 RETURN
640 :
650 REM ** FAKTUURNUMMERE ***
660 F$= "-FAKTUURNUMMER-" :S1=0
670 GOSUB 390
680 PRINT"WAT IS HET LAATST GEBRUIKTE FAKTUURNR. ";
690 INPUT F
700 IF  F< 0 OR F> 999999! THEN 670
710 RETURN
720 :
730 REM ** KLANTNUMMER ***
740 PRINT"KLANTNUMMER <STOP = 0> ";
750 INPUT K
760 IF K<0 OR K> 999999! THEN 740
770 RETURN
780 :
790 REM ** KLANT GEGEVENS ***
800 D=C-1
810 PRINT T$(D,1);
820 INPUT T$(D,2)
830 IF LEN(T$(D,2))>30 THEN T$(D,2)=LEFT$(T$(D,2),30)
840 RETURN
850 :
860 REM ** NAW-SCHOON  **
870 FOR I=1 TO 6 :T$(I,2) ="":NEXT I
880 RETURN
890 :


































































































































































































































































































































































































































4444





900 REM NAW OPVOEREN **
910 F$="-KLANTGEGEVENS-":S1=0
920 IF M=5 THEN 1000
930 N=0                             :REM NIEUWE FAKTUUR
940 GOSUB 390                       :REM KOP
950 GOSUB 870                       :REM NAW-SCHOON
960 GOSUB 740
970 IF K=0 THEN 1150
980 FOR C=2 TO 7 : GOSUB 800 :NEXT C
990 REM ** CORRECTIE **
1000 IF K=0 THEN 1150
1010 GOSUB 390
1020 PRINT"     CODE  OMSCHRIJVING        INHOUD"
1030 PRINT TAB(5)"1 = KLANTNUMMER...............";K 
1040 FOR C=1 TO 6
1050 PRINT TAB(4)C+1;TAB(7)"= "+T$(C,1);" ";T$(C,2)
1060 NEXT C
1070 PRINT"---------------------------------------------------------"
1080 PRINT"0= AKKOORD / 9 = OPNIEUW"
1090 PRINT"WAT IS UW KEUZE  ";
1100 INPUT C
1110 IF C=1 THEN GOSUB 740
1120 IF C> 1 AND C<8 THEN GOSUB 800 :REM NAW
1125 IF C=0 THEN 1150
1130 IF C=9 THEN 940
1140 IF C<> 0 THEN 1010
1150 RETURN
1160 :
1170 REM *** ARTIKELNUMMER ***
1180 PRINT"ARTIKELNUMMER <GEEN = -1 STOP =0>;
1190 INPUT A(X,1)
1200 IF A(X,1)<-1 OR  A(X,1) >999999! THEN 1180
1210 RETURN
1220 :
1230 REM *** OPSCHRIJVEN ***
1240 PRINT"OMSCHRIJVING ARTIKEL...................";
1250 INPUT A$(X)
1260 A$(X) =LEFT$ (A$(X),20)
1270 RETURN
1280 :
1290 REM *** PRIJS PER EENHEID **
1300 PRINT"WAT IS DE PRIJS PER EENHEID............";
1310 INPUT A(X,2)
1320 IF A(X,2) <0 THEN 1300
1330 RETURN
1340 :
1350 REM *** BTW PERCENTAGE ***
1360 FOR J=1 TO 3
1370 PRINT J;"=";B(J);"%";
1380 NEXT J
1390 PRINT
1400 PRINT"WELK BTW-PERCENTAGE  <GEEF CODE>.......";
1410 INPUT H
1420 IF H<1 OR H>3 THEN 1400
1430 A(X,3) =H
1440 RETURN
1450 :
1460 REM AANTAL EENHEDEN
1470 PRINT"HOEVEEL EENHEDEN.......................";
1480 INPUT A(X,4)
1490 IF A(X,4)=0 THEN 1470
1500 RETURN
1510 :
1520 REM ** BEDRAG + BTW-BEDRAG ***
1530 A(X,6) =A(X,2) * A(X,4)                :REM AANT * PRIJS
1540 A(X,5) =A(X,6) * B(A(X,3)) / 100       :REM BTW EXCL.
1550 IF B1 =0 THEN 1580                     :REM B1=1 INCL BTW
1560 A(X,5) =A(X,6) * B(A(X,3)) / (100 + B(A(X,3)))
1570 REM ** AFRONDEN OP CENTEN **
1580 A(X,6) =INT(A(X,6) * 100 + .5) / 100
1590 A(X,5) =INT(A(X,5) * 100 + .5) / 100
1600 RETURN
1610 :
1620 REM ** AFDRUK REGEL- SCHERM **
1630 PRINT L;
1640 IF A(L,1) <> -1 THEN PRINT TAB(5)A(L,1);
1650 PRINT TAB(12)A$(L);
1660 B=A(L,2) : GOSUB 1730 : PRINT TAB(30+Z)A$;
1670 PRINT TAB(45)A(L,4);
1680 B=A(L,6) : GOSUB 1730 : PRINT TAB(52+Z)A$;
1690 H=A(L,3) : PRINT TAB(66) B(H) ;"%"
1700 RETURN 
1710 :
1720 REM ** POSITIONEREN **
1730 B$= "--" :W=B-INT(B)
1740 A$=STR$(INT(B))
1750 IF W=0 THEN 1790
1760 W=INT(W*100 +.5) :B$=STR$(W)
1770 B$= "00"+RIGHT$(B$,LEN(B$)-1)
1780 B$=RIGHT$(B$,2)
1790 A$=A$+","+B$
1800 IF B<> 0 THEN 1820
1810 A$="-  "
1820 Z=10-LEN(A$)
1830 RETURN
1840 :
1850 REM ** INVOER FAKTUURREGELS **
1860 F$="-INVOER FAKTUURREGELS-"
1870 IF K=0 THEN 2020
1880 S1=1 :GOSUB 390 :REM KOP
1890 IF N=0 THEN 1910
1900 L=N :GOSUB 1630 :REM ** REGEL SCHERM
1910 X=N +1 : PRINT:GOSUB 1180 :REM ARTIKELNR.
1920 IF A(X,1)=0 THEN 2010
1930 GOSUB 1240               :REM OMSCHRIJVING
1940 GOSUB 1300               :REM PRIJS/EENH
1950 GOSUB 1360               :REM BTW-PERC.
1960 GOSUB 1470               :REM AANTAL
1970 GOSUB 1530               :REM BEDRAG
1980 N=X
1990 T=T+A(X,6)
2000 IF N< 35  THEN 1880
2010 GOSUB 2050
2020 RETURN 
2030 :
2040 REM ** DISPLAY **
2050 IF N=0 OR K=0 THEN 2380
2060 D=1
2070 F$="-DISPLAY-"  : S1=1
2080 B=T :GOSUB 1730 :S$=A$:P=Z:REM TOTAALBEDR.
2090 GOSUB 390
2100 FOR L=D TO D + 3
2110 IF L> N THEN 2130
2120 GOSUB 1630               :REM ** REGELSCHERM
2130 NEXT L
2135 PRINT TAB(55)"=========="
2140 PRINT TAB(20)"TOTAAL FAKTUUR";
2150 IF B1=0 THEN PRINT " EXCL. BTW";".......";     
2160 IF B1=1 THEN PRINT " INCL. BTW";".......";
2170 PRINT TAB(52+P)S$
2180 PRINT TAB(1)"-------------------------------------------------------------------------"
2200 PRINT"0 = AKKOORD            3 = CORRECTIE"
2210 PRINT"1 = VOORUIT            4 = TOEVOEGEN"
2220 PRINT"2 = ACHTERUIT          9 = VERWIJDEREN"
2223 PRINT:PRINT
2224 IF N=35 THEN PRINT"FAKTUUR IS VOL U HEBT REEDS 35 REGELS GEBRUIKT !"
2225 IF N=35 THEN PRINT"KEUZE MEER REGEL INVOER WORDT AUTOMATISCH OVER GETRANSPORTEERD !"
2226 PRINT
2230 PRINT"WAT IS UW KEUZE ";
2240 INPUT Q
2250 IF Q= 1 THEN D=D +3
2260 IF D>N THEN D=N
2270 IF Q=2 THEN D=D-3
2280 IF D<=0 THEN D=1
2290 IF Q<> 3 AND Q <> 9 THEN 2340
2300 REM ** WELKE REGEL **
2310 PRINT "WELKE REGEL ";
2320 INPUT X
2330 IF X<1 OR X>N THEN 2350
2340 IF Q=3 THEN GOSUB 2410       :REM CORRECTIE
2345 IF Q=4 AND N=2 THEN 2380
2350 IF Q=4 THEN GOSUB 1860        :REM INVOER
2360 IF Q=9 THEN GOSUB 2620       :REM VERWIJDEREN
2370 IF Q <> 0 AND N > 0 THEN 2070
2380 RETURN
2390 :
2400 REM ** CORRECTIE **
2410 F$="-CORRECTIE-REGELS-" :S1=1
2420 GOSUB 390
2430 L=X :GOSUB 1630
2440 PRINT TAB(1)"-------------------------------------------------------------------------"
2460 PRINT"0 = STOP               3 = PRIJS PER EENHEID"
2470 PRINT"1 = ARTIKELNUMMER      4 = BTW-PERC"
2480 PRINT"2 = OMSCHRIJVING       5 = AANTAL EENHEDEN"
2490 PRINT"WAT IS UW KEUZE ";
2500 INPUT C
2510 T=T-A(X,6)
2520 IF C=1 THEN GOSUB 1180 :REM ARTIKELNR.
2530 IF C=2 THEN GOSUB 1240 :REM OMSCHRIJVING
2540 IF C=3 THEN GOSUB 1300 :REM PRIJS PER EENH.
2550 IF C=4 THEN GOSUB 1360 :REM BTW-PERCENTAGE.
2560 IF C=5 THEN GOSUB 1470 :REM AANTAL EENHEDEN.
2570 GOSUB 1530 :T=T+A(X,6)
2580 PRINT:PRINT:
2590 RETURN 
2600 :
2610 REM ** VERWIJDEREN **
2620 F$="-REGELS VEWIJDEREN-" :S1=1
2630 GOSUB 390
2640 L=X :GOSUB 1630
2650 PRINT"-----------------------------------------------------"
2660 B$="ZEKER WETEN" :GOSUB 310
2670 IF S=2 THEN 2770
2680 T=T - A(X,6):IF X=N THEN 2750
2690 FOR I=X TO N -1
2700 A$(I)=A$(I+1)
2710 FOR J=1 TO 6
2720 A(I,J) = A(I+1,J)
2730 NEXT J
2740 NEXT I
2750 L=L - 1 :IF L< 1 THEN L=1
2760 N=N -1 :IF N < 1 THEN N=0
2770 RETURN
2780 :
2790 REM ** PRINT - KOP **
2800  LPRINT LF$     :   LPRINT TAB(25) N1$;" - ";N2$
2810  LPRINT TAB(13)N3$ +" - " +N4$ +" - TELEFOON - " +N5$
2820  LPRINT TAB(18)"POSTGIRO: " +N6$ + " - ";
2830  LPRINT "BANKRELATIE: " + N7$
2840  LPRINT TAB(23)N8$
2850 RETURN
2860 :
2870 REM ** AFSLUITEN EXCL BTW **
2880  LPRINT TAB(57)"----------"     
2890 B=T9 : GOSUB 1730
2900  LPRINT TAB(35)"SUBTOTAAL "; TAB(57+Z)A$:X=X+2
2910 FOR I= 1 TO 3
2920 IF T(I) =0 THEN 2950
2930 B=T(I):GOSUB 1730 :T9=T9+B:X=X+1
2940  LPRINT TAB(35)"BTW-";B(I);"%";TAB(57+Z)A$
2950 NEXT I
2960 B=T9 : GOSUB 1730 :  PRINT TAB(57)"----------"    
2970  LPRINT TAB(35)"FAKTUURBEDRAG";TAB(57+Z)A$
2980  LPRINT TAB(57)"=========="  : X=X + 3
2990 RETURN
3000 :
3010 REM AFSLUITEN **
3020  LPRINT TAB(57)"----------"  
3030 B=T9: GOSUB 1730
3040  LPRINT TAB(35)"FAKTUURBEDRAG";TAB(57+Z)A$
3050  LPRINT TAB(57)"=========="     
3060  LPRINT      :REM LINEFEED
3070  LPRINT TAB(7)"INBEGREPEN BTW";:H=0
3080 FOR I= 1 TO 3
3090 IF T(I) =0 THEN 3130
3100 B=T(I) : GOSUB 1730
3110  LPRINT TAB(H*18+22)B(I);"% FL ";A$;
3120 H=H+1
3130 NEXT I
3140 X=X +4
3150 RETURN
3160 :
3170 REM EIND FAKTUUR
3180 IF X>57 THEN 3200
3190 FOR H=X TO 57 :  LPRINT     : NEXT H
3195 LPRINT TAB(8)"-";N10$;"-"
3196 LPRINT TAB(8)"-";N11$;"-"
3197 LPRINT TAB(8)"-";N12$;"-"
3198 LPRINT
3200  LPRINT TAB(8)"BETALING BINNEN 30 DAGEN NA FAKTUURDATUM."
3210  LPRINT     
3220  LPRINT TAB(8)"VAN TOEPASSING ZIJN ONZE VOORWAARDEN VOOR ";
3230  LPRINT "VERKOOP EN LEVERING"
3240  LPRINT TAB(8)"GEDEPONEERD TER GRIFFIE DER ARRONDISSEMENTS";
3250  LPRINT "BANK TE HENGELO (O)"
3260  LPRINT TAB(8)"ONDER NUMMER 88997/1974."
3265 LPRINT :LPRINT
3266 LPRINT :LPRINT:LPRINT    
3270 RETURN
3280 :
3290 REM ** PRINTEN **
3300 REM ** NAAR PRINTER **
3310 B$="STAAT DE PRINTER AAN " :GOSUB 310
3320 IF S=2 THEN 3870
3330 L$="ORGINEEL"
3340 IF G<>-1 THEN 3360
3350 G=1      : F=F+1                 :REM FAKTUURNR. +1
3360 FOR Y=1 TO P1 + 1
3370 IF Y<> 1 THEN L$="DUPLICAAT " +STR$(Y-1)
3380 T9=0:T(1)=0 :T(2)=0 :T(3)=0       
3390 FOR I=1 TO N
3400 IF I <> 1 AND I/20-INT(I/20) <> 0 THEN 3760
3410 IF I=1 THEN 3460
3420 B=T9 :GOSUB 1730               :REM POSITIONEREN **
3430  LPRINT TAB(57)"----------"                                    
3440  LPRINT TAB(35)"TRANSPORT";TAB(57+Z)A$:X=X+2
3450 GOSUB 3180
3460 LPRINT LF$ 
3470 GOSUB 2800                  :REM PRINT KOP           
3480 REM ** ADRES KLANT **
3490 FOR J= 1 TO 5 : LPRINT    :NEXT J : REM OPSCHUIVEN
3500  LPRINT TAB(10)T$(1,2)            : REM NAAM KLANT
3510  LPRINT TAB(10)T$(2,2)            : REM T.A.V.
3520  LPRINT TAB(10)T$(3,2);           :REM ADRES + HUISNR.
3530  LPRINT  TAB(50)"FAKTUUR - ";L$
3540  LPRINT TAB(10)T$(4,2) +" " + T$(5,2);
3550  LPRINT TAB(49)F                  : REM FAKTUURNR.
3560  LPRINT                           :REM LINEFEED
3570  LPRINT TAB(50)"DATUM:          KLANTNUMMER:"
3580  LPRINT TAB(50)D$;TAB(65)K
3590  LPRINT TAB(50)"BIJ BETALING S.V.P. VERMELDEN"
3600  LPRINT TAB(10)"UW REFERENTIE : ";T$(6,2)
3610 LPRINT:LPRINT             :REM 2 maal line feed
3620  LPRINT TAB(50)"PRIJS"
3630  LPRINT TAB(7)"AANTAL.     OMSCHRIJVING.       ART.";TAB(51)"PER";
3640  LPRINT TAB(60)"BEDRAG       BTW"
3650  LPRINT"--";TAB(49)"EENHEID";
3660 IF B1 =1 THEN  LPRINT TAB(61)"INCL.";
3670 IF B1 =0 THEN  LPRINT TAB(61)"EXCL.";
3680  LPRINT TAB(78)"--"
3690  LPRINT TAB(1)"-------------------------------------------------------------------------------"
3710  LPRINT     
3720 X=29
3730 IF I=1 THEN 3760
3740  LPRINT TAB(39)"TRANSPORT";TAB(62+Z)A$:X=X+1
3750 REM ** FAKTUURREGELS **
3760  LPRINT TAB(7)A(I,4);
3770  LPRINT TAB(19)A$(I);
3780 IF A(I,1) <> -1 THEN  LPRINT TAB(40)A(I,1);
3790 B=A(I,2) : GOSUB 1730 :  LPRINT TAB(45+Z)A$; : REM PRIJS
3800 B=A(I,6) : GOSUB 1730 :  LPRINT TAB(57+Z)A$; : REM BEDRAG
3810 H=A(I,3) :  LPRINT TAB(72)B(H);TAB(76)"%"   :REM BTW
3820 T9=T9 + A(I,6) :T(H)=T(H) + A(I,5) :X=X + 1
3830 NEXT I
3840 ON B1+1 GOSUB 2880,3010
3850 GOSUB 3180
3860 NEXT Y
3870 RETURN 
3880 :
3890 REM ** NIEUW FAKTUUR **
3900 SI=1 : GOSUB 390
3910 B$="MOET HET FAKTUURNR MET 1 OMHOOG "
3920 GOSUB 310             :REM JA/NEE
3930 IF S=1 THEN G=-1
3940 RETURN
3950 :
3960 REM ** FAKTUUR AFDRUKKEN ? **
3970 S1=1 : GOSUB 390
3980 B$="FAKTUUR NOG AFDRUKKEN " : GOSUB 310
3990 IF S=1 THEN GOSUB 3310
4000 RETURN
4010 :
4020 REM ** MENU **
4030 F$="-MENU-":S1=0
4040 GOSUB 390            :REM KOP
4050 PRINT"0 = SYSTEEM VERLATEN"
4060 PRINT"1 = STARTWAARDEN VULLEN"
4070 PRINT"2 = NIEUWE KLANT + NIEUWE FAKTUUR"
4080 PRINT"3 = ZELFDE KLANT + NIEUWE FAKTUUR"
4090 PRINT"4 = BESTAANDE FAKTUUR CORRIGEREN"
4100 PRINT"5 = BESTAANDE KLANTGEGEVENS CORRIGEREN"
4110 PRINT"6 = FAKTUUR UITPRINTEN"
4113 PRINT"7 = KOP-FAKTUUR "
4115 PRINT"8 = WIJZIGING BTW
4120 PRINT:PRINT"WAT IS UW KEUZE ";
4130 INPUT M
4135 IF M= 7 THEN 4950
4140 IF Y4=0 AND M>1 THEN 4040
4150 IF M<0 OR M> 8 THEN 4040
4160 RETURN
4170 :
4180 REM ** STUURMODULE **
4190 GOSUB 140                                :REM INITIALISEREN
4200 GOSUB 4030                               :REM MENU
4205 IF M=0 THEN CHAIN "ADMIN"
4210 IF M<> 1 THEN 4250
4220 REM ** STARTWAARDEN VULLEN **
4230 GOSUB 510 :GOSUB 60  :GOSUB 5500  :REM FAKT-DATUM
4240 GOSUB 660                                :REM FAKT-NR
4250 IF M<> 2 AND M<> 3 THEN 4320 
4260 IF G=-1 THEN GOSUB 3970                  :REM FAKT-AFDR ?
4270 IF M<> 2 THEN 4300
4280 REM ** NIEUWE KLANT & NIEUWE FAKTUUR **
4290 GOSUB 910                                :REM KLANT-GEGEV
4300 T=0
4310 G=-1 : N=0 : GOSUB 1860                  :REM FAKTUUR
4320 IF M=4 THEN GOSUB 2050                    :REM FAKT-CORR
4330 IF M=5 THEN GOSUB 910                    :REM NAW-CORR
4340 IF M<> 4 AND M<> 5 THEN 4360     
4350 IF G=1 THEN GOSUB 3900                   :REM FAKTUUR + 1 ?
4360 IF M=6 THEN GOSUB 3310    :REM PRINTEN                               
4365 IF M=8 THEN GOSUB 8000
4370 IF M <>0 THEN 4200
4380 IF G=-1 THEN GOSUB 3970                  :REM FAKT-AFDRUK ?
4390 :
4400 REM **PRINTEN -B **
4410 REM ** NAAR PRINTER **
4420 B$="STAAT DE PRINTER AAN " :GOSUB 310
4430 IF S=2 THEN 4940
4440 L$="ORGINEEL"
4450 IF G<>-1 THEN 4470
4460 G=1 : F=F+1               :REM FAKTUURNR. +1
4470 FOR Y=1 TO P1 +1          :REM AANTAL KOPIEEN
4480 IF Y<> 1 THEN L$ ="DUPLICAAT " +STR$(Y-1)
4490 T9=0 :T(1)=0 :T(2)=0::T(3)=0
4500 FOR I=1 TO N
4510 OPEN "O",1,"EXTMELF"
4520 IF I=1 THEN 4570
4530 B=T9:GOSUB 1730           :REM ** POSITIONEREN
4540 PRINT TAB(62)"-----------"
4550 PRINT TAB(35)"TRANSPORT";TAB(62+Z)A$ :X=X+2
4560 :
4570 PRINT FF$
4580 :
4590 REM ** ADRES KLANT **
4600 FOR J=1 TO 5 :PRINT LF$:NEXT J:REM OPSCHUIVEN
4610 PRINT TAB(10)T$(1,2)           :REM NAAM KLANT
4620 PRINT TAB(10)T$(2,2)            :REM T.A.V.
4630 PRINT TAB(10)T$(3,2);           :REM ADRES+HUISNR.
4640 PRINT TAB(60)" - ";L$
4650 PRINT TAB(10)T$(4,2) + " " +T$(5,2);
4660 PRINT TAB(52)F                  :REM FAKTUURNR.
4670 PRINT LF$ :PRINT LF$
4680 PRINT LF$
4690 PRINT TAB(10)"UW REFERENTIE : ";T$(6,2)
4700 PRINT LF$ : PRINT LF$           :REM 2* LINEFEED
4710 PRINT TAB(54)"PRIJS"
4720 PRINT TAB(7)"AANTAL        OMSCHRIJVING";TAB(55)"PER";
4730 PRINT TAB(63)"BEDRAG      BTW"
4740 PRINT TAB(53)"EENHEID";
4750 IF B1 =1 THEN PRINT TAB(64)"INCL.";
4760 IF B1 =0 THEN PRINT TAB(64)"EXCL.";
4770 PRINT LF$
4780 PRINT LF$
4790 X=29
4800 IF I=1 THEN 4830
4810 PRINT TAB(39)"TRANSPORT";TAB(62+Z)A$:X=X+1
4820 REM ** FAKTUURREGELS **
4830 PRINT TAB(7)A(I,4);
4840 PRINT TAB(17)A$(I);
4850 IF A(I,1) <> -1 THEN PRINT TAB(42)A(I,1);
4860 B=A(I,2) :GOSUB 1730 :PRINT TAB(50+Z)A$;   :REM PRIJS
4870 B=A(I,6) :GOSUB 1730 :PRINT TAB(62+Z)A$;   :REM BEDRAG
4880 H=A(I,3) : PRINT TAB(74)B(H);TAB(78)"%"    :REM BTW
4890 T9=T9 +A(I,6) :T(H) =T(H)+A(I,5) :X=X+1
4900 NEXT I
4910 ON B1 + 1 GOSUB 2880,3010
4920 GOSUB 3180
4930 NEXT Y
4940 RETURN
4950 REM ** INITIALISEREN **
4960 REM KOP FAKTUUR
4970 F$="KOP-FAKTUUR INITIALISEREN":GOSUB 390
4980 PRINT:PRINT
4990 INPUT "NAAM BEDRIJF                 ";N1$
5000 INPUT "SOORT BEDRIJF                ";N2$
5010 INPUT "ADRES EN NUMMER              ";N3$
5020 INPUT "POSTC. WOONPLAATS            ";N4$
5030 INPUT "TELEFOON                     ";N5$
5040 INPUT "GIRO-NUMMER                  ";N6$
5050 INPUT "NAAM BANK EN NUMMER          ";N7$
5060 INPUT "INSCHRIJF K.V.K. EN PLAATS   ";N8$
5070 PRINT:PRINT:
5080 PRINT"1 = SAVE KOP-FAKTUUR "
5090 PRINT"2 = WIJZIGEN KOP-FAKTUUR "
5095 PRINT"3 = EXTRA MELDING ONDER FAKTUUR "
5100 INPUT"WAT IS UW KEUZE ";O
5110 IF O=1 THEN 6000
5120 IF O=2 THEN 4950
5125 IF O= 3 THEN 5200
5130 IF O<1 OR O>3 THEN 5080
5200 REM ** EXTRA REGELS ONDER FAKTUUR **
5210 F$="EXTRA MELDING ONDER FAKTUUR ":GOSUB 390
5220 GOSUB 300
5225 IF S= 2 THEN 4020
5230 PRINT
5235 PRINT"U KUNT NU UW EXTRA MELDING INVOEREN.
5236 PRINT"        *** VOORBEELD ***      "  
5237 PRINT "-REGEL 1-"
5238 PRINT "-REGEL 2-"
5239 PRINT "-REGEL 3-":PRINT
5260 PRINT
5270 INPUT "REG. 1";N10$
5280 INPUT "REG. 2";N11$
5285 INPUT "REG. 3";N12$
5290 PRINT " 1 = SAVE EXTRA MELDING "
5300 PRINT " 2 = WIJZIGEN           "
5310 INPUT "WAT IS UW KEUZE ";Y
5320 IF Y= 1 THEN 5400
5330 IF Y= 2 THEN 5200
5340 IF Y <1 OR Y>2 THEN 2580
5350 :
5360 RETURN
5400 REM : ***SAVE EXTRA MELDING ONDER FAKTUUR 
5402 F$="OPSLAAN EXTRA MELDING " :GOSUB 390
5403 GOSUB 300
5405 IF S=2 THEN 5290
5410 OPEN "O",1,"EXTMELF"
5420 PRINT #1,N10$           
5425 PRINT #1,N11$
5430 PRINT #1,N12$          
5440 CLOSE 
5450 :
5460 RETURN
5500 REM ** INLEZEN EXTRA MNELDING ONDER FAKTUUR **
5510 F$="INLEZEN EXTRA MELDING ":GOSUB 390 
5520 GOSUB 300
5530 IF S=2 THEN 4020
5540 OPEN "I",1,"EXTMELF"
5550 INPUT #1,N10$      
5560 INPUT #1,N11$       
5565 INPUT #1,N12$
5570 CLOSE
5580 :
5590 RETURN
6000 REM OPSLAAN KOP-FAKTUUR
6010 F$="OPSLAAN OP DISK KOP-FAKTUUR":GOSUB 390:GOSUB 300
6020 IF S=2 THEN GOTO 4020
6030 OPEN "O",1,"KOPFAKT"
6040 PRINT #1, N1$;",";N2$;",";N3$ 
6045 PRINT #1, N4$;",";N5$    
6046 PRINT #1,N6$;",";N7$     
6047 PRINT #1,N8$;","
6070 CLOSE
6080 :
6090 RETURN
8000 REM WIJZIGING BTW PERCENTAGE
8010 F$= "- WIJGIGING BTW CODE - ":     
8020 GOSUB 380
8025 PRINT " 0 = Geen wijziging BTW percentage "
8030 PRINT " 1 = BTW NUL-TARIEF      = 0 % ":B(1)=0
8040 PRINT " 2 = BTW TARIEF LAAG     = 5 % ":B(2)=5 
8050 PRINT " 3 = BTW TARIEF HOOG     =20 % ":B(3)=20 
8060 PRINT " Uw Keuze       ";
8070 INPUT U
8075 IF U=1 THEN PRINT "Welk BTW percentage wenst u ";:INPUT B(1)
8077 IF U=2 THEN PRINT "Welk BTW percentage wenst u ";:INPUT B(2)
8080 IF U=3 THEN PRINT "Welk BTW percentage wenst u ";:INPUT B(3)
8085 IF U<0 OR U > 3 THEN 8060
8100 RETURN
