********** 
* PCSYSS *
**********
* Dit programma initialiseert de werkbestanden voor PACS
* Het historisch bestand wordt via een apart programma gecreerd

* Zet bestandsnamen in gelijknamige variabelen
* Hierdoor is het later makkelijk over te gaan naar harddisk
*
* LET OP : drivenummer van harddisk is e:
* 
* LET OP : historisch bestand staat op a:
*
STORE 'e:pcfiopd'  TO opdracht
STORE 'e:pcfiopl'  TO oplage
STORE 'e:pcfiplan' TO planning
STORE 'e:pcfioff'  TO offertes
STORE 'e:pcficalc' TO calcdat
STORE 'e:pcfipl'   TO prod:descr
STORE 'a:pcfihist' TO historie
STORE 'e:pcfidum'  TO dummy

* Memory bestand bevat alle systeemvariabelen

STORE 'e:pcfimem'  TO memory

@  7, 9 SAY "U KUNT NU DE BESTANDEN AAN LATEN MAKEN VOOR HET PACS-SYSTEEM."
@  8, 9 SAY "LET OP : INDIEN U REEDS EERDER DEZE FUNKTIE HEEFT GEBRUIKT IS DE"
@  9, 9 SAY "INFORMATIE IN DE HUIDIGE BESTANDEN NIET MEER BESCHIKBAAR !!!"
STORE "." TO akk
IF FILE ('&opdracht')
   @ 11, 9 SAY "ATTENTIE :"
   @ 12,22 SAY "+---------------------------------+"
   @ 13,22 SAY "| ER BESTAAN REEDS PACS-BESTANDEN |"
   @ 14,22 SAY "+---------------------------------+"
   @ 16, 9 SAY "WILT U DE BESTANDEN OPNIEUW LATEN AANMAKEN (J/N)"
   DO WHILE .NOT. (akk $ 'JN')
      STORE "." TO akk
      @ 16,58 GET akk PICTURE '!'
      READ
      CLEAR GETS
   ENDDO
ELSE
   @ 11,9 SAY "WILT U DE BESTANDEN LATEN AANMAKEN (J/N)"
   DO WHILE .NOT. (akk $ 'JN')
      STORE "." TO akk
      @ 11,51 GET akk PICTURE '!'
      READ
      CLEAR GETS
   ENDDO
ENDIF

IF akk = 'J'

   @ 22,0 SAY "BESTANDEN WORDEN AANGEMAAKT."
   USE pcduopd
   COPY STRUCTURE TO &opdracht
   USE &opdracht
   INDEX ON prod:nr TO &opdracht

   USE pcduopl
   COPY STRUCTURE TO &oplage
   USE &oplage
   INDEX ON prod:nr TO &oplage

   USE pcduplan
   COPY STRUCTURE TO &planning
   USE &planning
   INDEX ON prod:nr TO &planning

   USE pcduoff
   COPY STRUCTURE TO &offertes
   USE &offertes
   INDEX ON prod:nr TO &offertes
   
   USE pcducalc
   COPY STRUCTURE TO &calcdat 
   USE &calcdat
   INDEX ON prod:nr TO &calcdat
   
   USE pcdupl
   COPY STRUCTURE TO &prod:descr
   USE &prod:descr
   STORE 0 TO count
   DO WHILE count < 99
      APPEND BLANK
      STORE count + 1 TO count
   ENDDO
   RELEASE count

   USE
ELSE 
   IF start:up
      STORE F TO return
      DO pcsyin
      QUIT TO "a:"
   ENDIF
ENDIF

   * Let op : SYSSTART moet nog wat andere variabelen klaarzetten

IF FILE ('&opdracht')
   IF akk = "J"
      STORE "00/00/00" TO sysdate
      STORE '*' TO cur:prod
   ENDIF
   RELEASE akk,start:up
   SAVE TO &memory
ENDIF

RETURN
*
* EINDE PROGRAMMA
*
