************
* PCDIMENU *
************
*
* Met deze programma's kunnen we de gegevens van de kaart, in dezelfde
* volgorde als op de kaart, op het beeldscherm weergeven. Een deel van 
* het beeldscherm blijft steeds hetzelfde, terwijl aan de hand van de
* keuzes een ander deel van het beeldscherm wordt gevuld.
*
* Totaliseer de totaal bestelde oplage
*  
STORE 0 TO m:oplage
USE &oplage INDEX &oplage
FIND &cur:prod
DO WHILE (cur:prod = prod:nr) .AND. .NOT. EOF
   STORE aant:best + m:oplage TO m:oplage
   SKIP + 1
ENDDO
USE
*
* Vindt de leverdatum
*
USE &planning INDEX &planning
FIND &cur:prod
STORE $(adr:drag,1,8) TO m:lev:dat
USE
USE &opdracht INDEX &opdracht
FIND &cur:prod
ERASE
@  1,10 SAY "--READER'S DIGEST PRODUCTION ADMINISTRATION CONTROL SYSTEM--"
@  2,10 SAY "------------------------- DE KAART -------------------------"
@  4, 0 SAY "+---------------------------------------------------+--------------------------+"
@  5, 0 SAY "| PRODUKT    LEVERDATUM    OPLAGE   AFLEVERADRES    |     NO C'SCHEMA"
@  5,70 SAY nr:camp
@  5,79 SAY "|"
@  6, 0 SAY "|"
@  6, 4 SAY produkt
@  6,14 SAY m:lev:dat
@  6,24 SAY STR(m:oplage,9)
@  6,36 SAY afl:adres
@  6,52 SAY "|       MAILDATUM"
@  6,70 SAY mail:dat
@  6,79 SAY "|"
@  7, 0 SAY "| ONDERDEEL"
@  7,13 SAY onderdeel
@  7,52 SAY "| PRODUKTIENUMMER"
@  7,70 SAY $(cur:prod,1,2) + "/" + $(cur:prod,3,5)
@  7,79 SAY "|"
@  8, 0 SAY "+---------------------------------------------------+--------------------------+"
STORE "." TO choice
DO WHILE (choice # "E")
   @  2,10 SAY "------------------------- DE KAART -------------------------"
   @ 10,28 SAY "1- BESTELBONGEGEVENS"
   @ 11,28 SAY "2- TECHNISCHE GEGEVENS"
   @ 12,28 SAY "3- DEADLINES"
   @ 13,28 SAY "4- PRIJSAANVRAGEN"
   @ 14,28 SAY "5- LEVERANCIERS"
   @ 15,28 SAY "6- OPLAGE GEGEVENS"
   @ 16,28 SAY "E- EINDE"
   @ 18,31 SAY "UW KEUZE"
   @ 22,58 SAY "HUIDIGE DATUM"
   @ 22,72 SAY sysdate
   STORE "." TO choice
   DO WHILE .NOT. (choice $ "123456E")
      STORE "." TO choice
      @ 18,40 GET choice PICTURE "!"
      READ
      CLEAR GETS
   ENDDO
   IF (choice # "E")
      STORE 9 TO line
      DO WHILE line < 22
         @ line,0
         STORE line + 1 TO line
      ENDDO
      DO CASE
         CASE choice = "1"
              DO pcdikrt1
         CASE choice = "2"
              DO pcdikrt2
         CASE choice = "3"
              DO pcdikrt3
         CASE choice = "4"
              DO pcdikrt4
         CASE choice = "5"
              DO pcdikrt5
         CASE choice = "6"
              DO pcdikrt6
      ENDCASE
      STORE "." TO akk
      @ 22,0 SAY "DRUK RETURN " GET akk
      READ
      CLEAR GETS
      @ 22,0 SAY "               "
      STORE 9 TO line
      DO WHILE line < 22
         @ line,0
         STORE line + 1 TO line
      ENDDO
   ENDIF
ENDDO
USE
RETURN
*
* EINDE PROGRAMMA
*
