**********
* PCPRAD *
**********

* Toevoegen nieuw produktienummer
* Dit nummer bestaat uit de productline en het bestelbonnummer
* Voor elk nieuw produktienummer wordt per werkbestand minimaal
* 1 record toegevoegd


STORE 0 TO m:prod
STORE 0 TO m:best

@ 7,7 SAY "U KUNT NU EEN NIEUW PRODUKTIENUMMER TOEVOEGEN. DIT NUMMER BESTAAT"
@ 8,7 SAY "UIT HET PRODUCTLINE-NUMMER EN HET BESTELBONNUMMER."
STORE F TO finished  
DO WHILE .NOT. finished
   STORE "." TO akk
   DO WHILE .NOT. (akk $ "JN")
      @ 10,20 SAY "PRODUCTLINE-NUMMER " GET m:prod PICTURE "##"
      @ 11,20 SAY "BESTELBONNUMMER    " GET m:best PICTURE "#####"
      @ 20,68 SAY "AKKOORD " GET akk PICTURE "!"
      READ
      CLEAR GETS
      DO WHILE .NOT. (akk $ "JN") 
         STORE "." TO akk
         @ 20,68 SAY "AKKOORD " GET akk PICTURE "!"
         READ
         CLEAR GETS
      ENDDO
   
      IF akk = "N"
         STORE "." TO again
         DO WHILE .NOT. (again $ "JN")
            STORE "." TO again
            @ 20,59 SAY "OPNIEUW INTIKKEN " GET again PICTURE "!"
            READ
            CLEAR GETS
         ENDDO
         IF again = "J" 
            STORE "." TO akk 
            @ 20,59 SAY "                    "
         ELSE 
            STORE T TO finished
         ENDIF
      ENDIF
   ENDDO 
   IF akk = "J"
 
      STORE $(STR(m:prod+100,3),2,2) + $(STR(m:best+100000,6),2,5) TO m:prod:nr

      SET EXACT ON

      USE &opdracht INDEX &opdracht
      FIND &m:prod:nr
      IF (#>0)
         STORE "." TO akk
         @ 22,0 SAY "PRODUKTIENUMMER IS REEDS AANWEZIG, DRUK RETURN " GET akk
         READ
         @ 22,0 SAY "                                                  "
      ELSE 
         @ 22,0 SAY "PRODUKTIENUMMER WORDT TOEGEVOEGD."
         STORE T TO finished

         APPEND BLANK
         REPLACE prod:nr WITH m:prod:nr,prod:line WITH m:prod, ;
                 best:bonnr WITH m:best, hist:file WITH F

         USE &oplage INDEX &oplage
         APPEND BLANK
         REPLACE prod:nr WITH m:prod:nr

         USE &planning INDEX &planning
         APPEND BLANK
         REPLACE prod:nr WITH m:prod:nr

         USE &offertes INDEX &offertes
         APPEND BLANK
         REPLACE prod:nr WITH m:prod:nr

         USE &calcdat INDEX &calcdat
         APPEND BLANK
         REPLACE prod:nr WITH m:prod:nr

         STORE m:prod:nr TO cur:prod

      ENDIF
   ENDIF
ENDDO finished
USE

RELEASE m:prod,m:best,m:prod:nr,finished,again,akk
SAVE TO &memory
RETURN
*
* EINDE PROGRAMMA
*
